RichMedia+

var fun:Function = function ():void{
 // init. function static member
 var proto:Object = arguments.callee.prototype;
 proto.name ||= "Static Function Variable";
 proto.count ||= 0;
 
 trace(proto.name, proto.count++);
}
 
fun(); // Static Function Variable 0
fun(); // Static Function Variable 1
fun(); // Static Function Variable 2

package com.ticore.utils {
 import flash.display.Sprite;
 import flash.events.Event;
 import flash.text.TextField;
 
 /**
  * Stage scale detector class, able to detect concatenated scale change in show all or exact fit mode.
  * @author Ticore Shih - http://ticore.blogspot.com/
  */
 [Event(name="change", type="flash.events.Event")]
 public class StageScaleDetectorAdv extends Sprite {
 
  public function StageScaleDetectorAdv() {
   visible = false;
 
   // txtH.textWidth 僅反映出 stageScaleX 變化
   txtH.text = "-";
   txtH.rotation = 90;
   txtH.scaleX = txtH.scaleY = precision;
   stdTextWidth = txtH.textWidth;
   addChild(txtH);
 
   // txtV.width 僅反映出 stageScaleY 對 stageScaleX 比例變化
   txtV.text = "-";
   txtV.autoSize = "left";
   txtV.scaleX = txtV.scaleY = 1 / precision;
   stdTextRatio = (txtV.width - 4 / precision) / (txtV.height - 4 / precision);
   addChild(txtV);
 
   addEventListener(Event.ENTER_FRAME, onEnterFrameHandler);
  }
 
  protected function onEnterFrameHandler(e:Event = null):void {
   validateNow();
  }
 
  /**
   * force update stageScaleX, stageScaleY immediately
   */
  public function validateNow():void{
   var textRatio:Number = (txtV.width - 4 / precision) / (txtV.height - 4 / precision);
 
   _stageScaleX_ = stdTextWidth / txtH.textWidth;
   _stageScaleY_ = _stageScaleX_ * textRatio / stdTextRatio;
 
   if (Math.abs(_stageScaleX_ - _preEmitstageScaleX_) + Math.abs(_stageScaleY_ - _preEmitstageScaleY_) > threshold) {
    _preEmitstageScaleX_ = _stageScaleX_;
    _preEmitstageScaleY_ = _stageScaleY_;
    dispatchEvent(new Event(Event.CHANGE));
   }
  }
 
 
  protected var txtH:TextField = new TextField();
  protected var txtV:TextField = new TextField();
 
  // 標準文字寬度
  protected var stdTextWidth:Number;
 
  // 標準文字寬高比
  protected var stdTextRatio:Number;
 
  // 放大 20 倍情況下 precision 保險最小值為 0.005
  protected var precision:Number = 0.005;
 
  // Scale 變化超過閾值才發出 Change 事件
  protected var threshold:Number = 0.001;
 
  protected var _stageScaleX_:Number = 0;
  protected var _stageScaleY_:Number = 0;
  protected var _preEmitstageScaleX_:Number = 0;
  protected var _preEmitstageScaleY_:Number = 0;
 
 
  /**
   * concatenated scaleX to final stage output
   */
  public function get stageScaleX():Number{
   return _stageScaleX_;
  }
 
  /**
   * concatenated scaleY to final stage output
   */
  public function get stageScaleY():Number{
   return _stageScaleY_;
  }
 }
}

package {
 import com.ticore.utils.StageScaleDetector;
 import com.ticore.utils.StageScaleDetectorAdv;
 
 import flash.display.Graphics;
 import flash.display.Sprite;
 import flash.display.StageScaleMode;
 import flash.events.Event;
 
 [SWF(frameRate="24")]
 public class Main extends Sprite {
 
  public var detector:StageScaleDetectorAdv = new StageScaleDetectorAdv();
  public var sp:Sprite = new Sprite();
 
  public function Main() {
   // stage.scaleMode = StageScaleMode.SHOW_ALL;
   stage.scaleMode = StageScaleMode.EXACT_FIT;
 
   addChild(detector);
 
   initBackground();
   initSprite();
 
   detector.addEventListener(Event.CHANGE, onScaleChangeHandler);
  }
 
  public function initBackground():void {
   var g:Graphics = this.graphics;
   g.lineStyle(10, 0x808080);
   g.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
  }
 
  public function initSprite():void {
   var g:Graphics = sp.graphics;
   g.lineStyle(3, 0);
   g.beginFill(0, 0.5);
   g.drawRect(0, 0, 100, 100);
   g.endFill();
   addChild(sp);
  }
 
  public function onScaleChangeHandler(e:Event):void{
   var detector:StageScaleDetectorAdv = e.target as StageScaleDetectorAdv;
   sp.scaleX = 1 / detector.stageScaleX;
   sp.scaleY = 1 / detector.stageScaleY;
   sp.x = (stage.stageWidth - sp.width) / 2;
   sp.y = (stage.stageHeight - sp.height) / 2;
  }
 }
}

package {
 import flash.display.Sprite;
 import flash.text.TextField;
 
 public class TextFieldSize extends Sprite {
  public function TextFieldSize() {
   var txt:TextField = new TextField();
   txt.text = "0";
   txt.autoSize = "left";
 
   var sp:Sprite = new Sprite();
   sp.addChild(txt);
 
   trace(txt.width, txt.textWidth); // 64 60
 
   sp.scaleX = 2;
   trace(txt.width, txt.textWidth); // 34 30
 
   sp.scaleX = 3;
   trace(txt.width, txt.textWidth); // 24 20
  }
 }
}

package {
 import flash.display.Graphics;
 import flash.display.Sprite;
 import flash.display.StageScaleMode;
 import flash.events.Event;
 import flash.text.TextField;
 
 /**
  * Detect scale of stage with show all mode by TextField.textWidth
  * @author Ticore Shih - http://ticore.blogspot.com/
  */
 public class StageScaleDetector extends Sprite {
 
  public var txt:TextField = new TextField();
  public var stdTextWidth:Number;
 
  public var sp:Sprite = new Sprite();
 
  public function StageScaleDetector() {
   stage.scaleMode = StageScaleMode.SHOW_ALL;
 
   initDetector();
   initBackground();
   initSprite();
 
   addEventListener(Event.ENTER_FRAME, onStageResize);
  }
 
  public function initDetector():void {
   txt.text = "-";
   txt.rotation = 90;
   addChild(txt);
   stdTextWidth = txt.textWidth;
  }
 
  public function initBackground():void {
   var g:Graphics = this.graphics;
   g.lineStyle(10, 0x808080);
   g.drawRect(0, 0, stage.stageWidth, stage.stageHeight);
  }
 
  public function initSprite():void {
   var g:Graphics = sp.graphics;
   g.lineStyle(3, 0);
   g.beginFill(0, 0.5);
   g.drawRect(0, 0, 100, 100);
   g.endFill();
   addChild(sp);
  }
 
  public function onStageResize(e:Event):void {
   var stageScale:Number = stdTextWidth / txt.textWidth;
   sp.scaleX = sp.scaleY = 1 / stageScale;
   sp.x = (stage.stageWidth - sp.width) / 2;
   sp.y = (stage.stageHeight - sp.height) / 2;
  }
 }
}