<?xml version="1.0" encoding="utf-8"?>
<s:Panel xmlns:fx="http://ns.adobe.com/mxml/2009"
  xmlns:s="library://ns.adobe.com/flex/spark"
  xmlns:mx="library://ns.adobe.com/flex/mx"
  width="400" height="300" title="Custom Cursor Panel 1"
  rollOver="onRollOverHandler(event);"
  rollOut="onRollOutHandler(event);">
 <fx:Declarations>
  <flash:TextField id="cursorTxt" xmlns:flash="flash.text.*" border="true" autoSize="left" />
 </fx:Declarations>
 <fx:Script>
  <![CDATA[
   import mx.core.IChildList;
 
   protected var cursorID:int;
 
   public function onRollOverHandler(e:MouseEvent):void{
    cursorID = cursorManager.setCursor(Sprite);
 
    var cursorChildren:IChildList = systemManager.cursorChildren;
    if (!cursorChildren) return;
    var cursorHolder:Sprite = cursorChildren.getChildByName("cursorHolder") as Sprite;
    if (!cursorHolder || !cursorHolder.numChildren) return;
    var cursor:Sprite = cursorHolder.getChildAt(0) as Sprite;
    if (!cursor) return;
    cursor.addChildAt(cursorTxt, 0);
 
    addEventListener(MouseEvent.MOUSE_MOVE, onMouseEventHandler);
    addEventListener(MouseEvent.MOUSE_DOWN, onMouseEventHandler);
    addEventListener(MouseEvent.MOUSE_UP, onMouseEventHandler);
   }
 
   public function onRollOutHandler(e:MouseEvent):void{
    cursorManager.removeCursor(cursorID);
    removeEventListener(MouseEvent.MOUSE_MOVE, onMouseEventHandler);
    removeEventListener(MouseEvent.MOUSE_DOWN, onMouseEventHandler);
    removeEventListener(MouseEvent.MOUSE_UP, onMouseEventHandler);
   }
 
   public function onMouseEventHandler(e:MouseEvent):void{
    cursorTxt.text = e.type + " ("+ e.localX + " : " + e.localY + ")";
   }
  ]]>
 </fx:Script>
</s:Panel>

package com.ticore.utils  {
 import flash.display.DisplayObject;
 import flash.display.Sprite;
 
 /**
  * 提供一個 proxy 類別，給 Flex CursorManager 設定 cursor
  * CursorProxy 另外宣告一靜態的 getter/setter 供存取 cursor 實體
  * 每次 CursorProxy 實體被創建時，都會將靜態 cursor 實體加入自己 display list 下
  * 
  * @author Ticore Shih
  */
 public class CursorProxy extends Sprite {
 
  static protected var _cursor_:DisplayObject;
 
  static public function get cursor():DisplayObject{
   return _cursor_;
  }
 
  static public function set cursor(value:DisplayObject):void{
   _cursor_ = value;
   if (!_cursorProxy_) return;
   while (_cursorProxy_.numChildren) {
    _cursorProxy_.removeChildAt(0);
   }
   _cursorProxy_.addChild(_cursor_);
  }
 
 
  static protected var _cursorProxy_:CursorProxy;
 
  public function CursorProxy() {
   _cursorProxy_ = this;
   if (_cursor_) _cursorProxy_.addChild(_cursor_);
  }
 }
}

<?xml version="1.0" encoding="utf-8"?>
<s:Panel xmlns:fx="http://ns.adobe.com/mxml/2009"
  xmlns:s="library://ns.adobe.com/flex/spark"
  xmlns:mx="library://ns.adobe.com/flex/mx"
  width="400" height="300" title="Custom Cursor Panel 1"
  rollOver="onRollOverHandler(event);"
  rollOut="onRollOutHandler(event);">
 <fx:Declarations>
  <flash:TextField id="cursorTxt" xmlns:flash="flash.text.*" border="true" autoSize="left" />
 </fx:Declarations>
 <fx:Script>
  <![CDATA[
   import com.ticore.utils.CursorProxy;
   import mx.core.IChildList;
 
   protected var cursorID:int;
 
   public function onRollOverHandler(e:MouseEvent):void{
 
    cursorID = cursorManager.setCursor(CursorProxy);
    CursorProxy.cursor = cursorTxt;
    addEventListener(MouseEvent.MOUSE_MOVE, onMouseEventHandler);
    addEventListener(MouseEvent.MOUSE_DOWN, onMouseEventHandler);
    addEventListener(MouseEvent.MOUSE_UP, onMouseEventHandler);
   }
 
   public function onRollOutHandler(e:MouseEvent):void{
    cursorManager.removeCursor(cursorID);
    removeEventListener(MouseEvent.MOUSE_MOVE, onMouseEventHandler);
    removeEventListener(MouseEvent.MOUSE_DOWN, onMouseEventHandler);
    removeEventListener(MouseEvent.MOUSE_UP, onMouseEventHandler);
   }
 
   public function onMouseEventHandler(e:MouseEvent):void{
    cursorTxt.text = e.type + " ("+ e.localX + " : " + e.localY + ")";
   }
  ]]>
 </fx:Script>
</s:Panel>

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009" 
     xmlns:s="library://ns.adobe.com/flex/spark" 
     xmlns:mx="library://ns.adobe.com/flex/mx">
 <fx:Script>
  <![CDATA[
   Mod;
  ]]>
 </fx:Script>
 <s:layout>
  <s:VerticalLayout verticalAlign="middle" horizontalAlign="center" />
 </s:layout>
 <s:ModuleLoader id="modLdr" url="Mod.swf" width="50%" height="50%"/>
</s:Application>

<?xml version="1.0" encoding="utf-8"?>
<s:Module xmlns:fx="http://ns.adobe.com/mxml/2009"
  xmlns:s="library://ns.adobe.com/flex/spark"
  xmlns:mx="library://ns.adobe.com/flex/mx"
  width="100%" height="100%">
 <s:Panel width="100%" height="100%" title="Module" />
</s:Module>

<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009" 
     xmlns:s="library://ns.adobe.com/flex/spark" 
     xmlns:mx="library://ns.adobe.com/flex/mx">
 <fx:Script>
  <![CDATA[
   Mod;
  ]]>
 </fx:Script>
 <s:layout>
  <s:VerticalLayout verticalAlign="middle" horizontalAlign="center" />
 </s:layout>
 <s:ModuleLoader id="modLdr" url="Mod.swf" width="50%" height="50%"
   ready="event.target.child.styleManager.initProtoChainRoots();" />
</s:Application>

package com.ticore.utils {
 /**
  * 排列組合公用函式，可以對傳入的二維參數陣列
  * 找出各種組合，並將結果陣列回傳
  * 
  * @param args 任意數量的二維參數陣列
  * @param res 欲與其它條件再組合的結果陣列
  * @return 二維結果陣列
  * @author Ticore Shih
  * 
  * @example 以下例子會找出 [A, B] 與 [0, 1, 2] 所有可能的組合
  * <listing version="3.0">
  * trace(crossJoin([["A", "B"], [0, 1, 2]]).join("\n"));
  * </listing>
  */
 public function crossJoin(args:Array, res:Array = null):Array{
  args.forEach(function(o0:*, i0:int, a0:Array):void{
   (res ||= [[]]).splice(0).forEach(function(o1:*, i1:int, a1:Array):void{
    o0.forEach(function(o2:*, i2:int, a2:Array):void{
     res.push(o1.concat(o2));
    });
   });
  });
  return res;
 }
}

<?xml version="1.0" encoding="utf-8"?>
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009"
  xmlns:s="library://ns.adobe.com/flex/spark"
  xmlns:mx="library://ns.adobe.com/flex/mx">
 <fx:Script>
  <![CDATA[
   import org.robotlegs.mvcs.*;
 
   // include RobotLegs framework.
   Actor;
   Command;
   Context;
   Mediator;
  ]]>
 </fx:Script>
 <s:ModuleLoader url="modules/RLModule.swf" />
</s:Application>

<?xml version="1.0" encoding="utf-8"?>
<s:Module xmlns:fx="http://ns.adobe.com/mxml/2009"
  xmlns:s="library://ns.adobe.com/flex/spark"
  xmlns:mx="library://ns.adobe.com/flex/mx" xmlns:modules="modules.*">
 <fx:Declarations>
  <modules:RLModuleContext contextView="{this}" />
 </fx:Declarations>
</s:Module>

package modules {
 import flash.system.ApplicationDomain;
 
 import org.robotlegs.mvcs.Context;
 
 public class RLModuleContext extends Context {
 
  override public function startup():void{
   mediatorMap.mapView(RLModule, RLModuleMediator);
  }
 }
}

package modules {
 import org.robotlegs.mvcs.Mediator;
 
 public class RLModuleMediator extends Mediator {
 
  [Inject]
  public var view:RLModule;
 }
}

package {
 import com.ticore.obfu.SupClass;
 
 import flash.display.Loader;
 import flash.display.Sprite;
 import flash.events.Event;
 import flash.net.URLRequest;
 import flash.system.ApplicationDomain;
 import flash.system.LoaderContext;
 
 /**
  * Main 主程式 SWF
  * 持有共用的 SupClass 類別定義
  * 依據自身 application domain 產生 child domain
  * 用來載入繼承 SupClass 的外部 SWF 模組
  */
 [SWF(width="300", height="200")]
 public class Main extends Sprite {
 
  public var currAppDom:ApplicationDomain = ApplicationDomain.currentDomain;
  public var childAppDom:ApplicationDomain = new ApplicationDomain(currAppDom);
 
  public var ldr:Loader = new Loader();
 
  public var req:URLRequest = new URLRequest("Mod.swf");
  public var ldrCxt:LoaderContext = new LoaderContext(false, childAppDom);
 
  public function Main() {
   // 明確引用父類別定義，編入 parent application domain
   SupClass;
 
   ldr.contentLoaderInfo.addEventListener(Event.COMPLETE, onLoadCompleteHandler);
   ldr.load(req, ldrCxt);
   addChild(ldr);
  }
 
  public function onLoadCompleteHandler(e:Event):void{
   trace("onLoadCompleteHandler();");
  }
 }
}

package com.ticore.obfu {
 import flash.display.Bitmap;
 import flash.display.IBitmapDrawable;
 import flash.display.Sprite;
 
 /**
  * 共用的 SupClass 類別定義
  * 帶有 protected getter/setter 且型別為 interface
  */
 public class SupClass extends Sprite {
 
  protected var _foo_:IBitmapDrawable = new Bitmap();
 
  protected function get foo():IBitmapDrawable {
   return _foo_;
  }
 
  protected function set foo(value:IBitmapDrawable):void{
   _foo_ = value;
  }
 }
}

package  {
 import com.ticore.obfu.SupClass;
 
 import flash.display.Sprite;
 import flash.text.TextField;
 
 /**
  * 外部 SWF 模組
  * 繼承共用的 SupClass 類別定義
  * 嘗試用不同方式存取 SupClass protected getter member
  */
 [SWF(width="300", height="200")]
 public class Mod extends SupClass {
 
  public var txt:TextField = new TextField();
 
  public function Mod() {
   init();
   doTrace(new Date());
 
   // 直接呼叫 super protected getter member 會得到 error
   try {
    doTrace("foo:", foo);
   } catch (e:Error) {
    doTrace(e);
   }
 
   // 用 with block
   with (0) {
    doTrace("foo:", foo);
   }
 
   // 用關聯陣列存取算子
   doTrace("foo:", this["foo"]);
  }
 
 
  public function init():void{
   txt.wordWrap = true;
   txt.width = 250;
   txt.height = 150;
   txt.x = txt.y = 25;
   txt.border = true;
   addChild(txt);
  }
 
  public function doTrace(...args):void{
   trace.apply(null, args);
   txt.appendText(args.join(" ") + "\n");
  }
 }
}

package {
 import flash.display.Sprite;
 import flash.system.Capabilities;
 import flash.text.TextField;
 
 [SWF(width="300", height="200")]
 public class FL11ArrayIssue extends Sprite {
 
  public function FL11ArrayIssue() {
   trace(Capabilities.version, Capabilities.playerType);
 
   var ary:Array = new Array(5);
 
   /*/ 各種修正 FL 11 Array 的方式
   ary.push(undefined);
   ary.pop();
 
   ary.length++;
   ary.length--;
 
   ary.shift();
   ary.unshift(undefined);
 
   ary[0] = undefined;
 
   ary[0] = null;
 
   ary[0] = ary[0];
   //*/
 
   trace("[" + ary.join(" , ") + "]");
   ary.splice(2, 1, "X");
   trace("[" + ary.join(" , ") + "]");
   ary.splice(2, 1, "Y");
   trace("[" + ary.join(" , ") + "]");
   ary.splice(2, 1, "Z");
   trace("[" + ary.join(" , ") + "]");
  }
 }
}

package {
	import flash.display.Sprite;
	import flash.text.TextField;
	import flash.text.TextFormat;
 
	[SWF(width="300", height="200")]
	public class Main extends Sprite {
 
		public function Main() {
			var txt:TextField = new TextField();
			// txt.defaultTextFormat = new TextFormat("Microsoft JhengHei", 16);
			txt.defaultTextFormat = new TextFormat("微軟正黑體", 16);
			txt.text = "微軟正黑體";
			txt.x = 100;
			txt.y = 50;
			addChild(txt);
		}
	}
}

<languageVersion : 1.0;>
kernel PartialColor
<
    namespace : "PartialColor";
    vendor : "Ticore Shih";
    version : 1;
    description : "only keep saturation of assigned color";
>
{
 
    parameter float hue
    <
        defaultValue: 0.0;
        minValue: 0.0;
        maxValue: 360.0;
    >;
 
    parameter float range
    <
        defaultValue : 40.0;
        minValue : 0.0;
        maxValue : 180.0;
    >;
    input image4 src;
    output pixel4 dst;
 
    void evaluatePixel() {
        pixel4 inputColor = sampleNearest(src, outCoord());
        float minColor, maxColor, delta;
        float h, s, v;
        float r, g, b;
        float f, p, q, t;
        int i;
 
        r = inputColor.r; g = inputColor.g; b = inputColor.b;
 
        minColor = min(min(r , g) , b);
        maxColor = max(max(r , g) , b);
        delta = maxColor - minColor;
 
        // value
        v = maxColor;
        // saturation
        if (maxColor !=0.0 ) {
            s = delta / maxColor;
        }
 
        // hue
        if (maxColor == r) {
            h = (g - b) / delta;
        } else if (maxColor == g) {
            h = 2.0 + (b - r) / delta;
        } else {
            h = 4.0 + (r - g) / delta;
        }
        h *= 60.0;
        h = mod(h + 360.0, 360.0);
 
 
        float diff = min(mod(abs(hue - h - 360.0), 360.0), mod(abs(hue - h + 360.0), 360.0));
 
        // sine
 
        s *= sin(clamp(1.0 - diff / range, 0.0, 1.0) * 90.0 * 3.14159 / 180.0);
 
        s = clamp(s, 0.0, 1.0);
 
        if (s == 0.0) {
            r = g = b = v;
        } else {
            h /= 60.0;
            int i = int(floor(h));
            f = h - float(i);
 
            p = v * ( 1.0 - s );
            q = v * ( 1.0 - s * f );
            t = v * ( 1.0 - s * ( 1.0 - f ) );
 
            if (i == 0) {
                r = v; g = t; b = p;
            } else if (i == 1) {
                r = q; g = v; b = p;
            } else if (i == 2) {
                r = p; g = v; b = t;
            } else if (i == 3) {
                r = p; g = q; b = v;
            } else if (i == 4) {
                r = t; g = p; b = v;
            } else if (i == 5) {
                r = v; g = p; b = q;
            }
        }
 
        dst = pixel4(r, g, b, inputColor.a);
    }
}